Votre exemple est proche de pivoter, mais je ne pense pas que la fonctionnalité de pivot est utilisable sur celui-ci.
J'ai renommé votre exemple pour utiliser "department-person", au lieu de "child-parent", juste pour garder ma santé mentale.
Ainsi, les premières tables et des données
DECLARE @Department TABLE
(
DepartmentID int
,DepartmentName varchar(50)
)
DECLARE @Person TABLE
(
PersonID int
,PersonName varchar(50)
,DepartmentID int
)
INSERT INTO @Department
(DepartmentID, DepartmentName)
SELECT 1, 'Accounting' UNION
SELECT 2, 'Engineering' UNION
SELECT 3, 'Sales' UNION
SELECT 4, 'Marketing' ;
INSERT INTO @Person
(PersonID, PersonName, DepartmentID)
SELECT 1, 'Lyne', 1 UNION
SELECT 2, 'Damir', 2 UNION
SELECT 3, 'Sandy', 2 UNION
SELECT 4, 'Steve', 3 UNION
SELECT 5, 'Brian', 3 UNION
SELECT 6, 'Susan', 3 UNION
SELECT 7, 'Joe', 4 ;
Maintenant, je veux aplatir le modèle, je vais utiliser la table temporaire parce que j'ai les variables de table - mais une vue sur les « tables réelles » serait bon aussi.
/* Create a table with:
DepartmentID, DepartmentName, PersonID, PersonName, PersonListIndex
This could be a view instead of temp table.
*/
IF object_id('tempdb.dbo.#tmpTbl','U') IS NOT NULL
DROP TABLE #tmpTbl
;
WITH prs
AS (SELECT PersonID
,PersonName
,DepartmentID
,row_number() OVER (PARTITION BY DepartmentID ORDER BY PersonID) AS [PersonListIndex]
FROM @Person
),
dptprs
AS (SELECT d.DepartmentID
,d.DepartmentName
,p.PersonID
,p.PersonName
,p.PersonListIndex
FROM @Department AS d
JOIN prs AS p ON p.DepartmentID = d.DepartmentID
)
SELECT * INTO #tmpTbl FROM dptprs
-- SELECT * FROM #tmpTbl
colonnes dynamiques signifie requête dynamique, je vais composer ligne par ligne dans une table
/* Table to compose dynamic query */
DECLARE @qw TABLE
(
id int IDENTITY(1, 1)
,txt nvarchar(500)
)
/* Start composing dynamic query */
INSERT INTO @qw (txt) VALUES ('SELECT')
INSERT INTO @qw (txt) VALUES ('[DepartmentID]')
INSERT INTO @qw (txt) VALUES (',[DepartmentName]') ;
/* fetch max number of employees in a department */
DECLARE @i int ,@m int
SET @m = (SELECT max(PersonListIndex) FROM #tmpTbl)
/* Compose dynamic query */
SET @i = 1
WHILE @i <= @m
BEGIN
INSERT INTO @qw (txt)
SELECT ',MAX(CASE [PersonListIndex] WHEN '
+ cast(@i AS varchar(10)) + ' THEN [PersonID] ELSE NULL END) AS [Person_'
+ cast(@i AS varchar(10)) + '_ID]'
INSERT INTO @qw (txt)
SELECT ',MAX(CASE [PersonListIndex] WHEN '
+ cast(@i AS varchar(10)) + ' THEN [PersonName] ELSE NULL END) AS [Person_'
+ cast(@i AS varchar(10)) + '_Name]'
SET @i = @i + 1
END
/* Finish the dynamic query */
INSERT INTO @qw (txt) VALUES ('FROM #tmpTbl')
INSERT INTO @qw (txt) VALUES ('GROUP BY [DepartmentID], [DepartmentName]')
INSERT INTO @qw (txt) VALUES ('ORDER BY [DepartmentID]')
-- SELECT * FROM @qw
Et maintenant, concaténer toutes les lignes de requête dans une variable et exécuter
/* Create a variable with dynamic sql*/
DECLARE @exe nvarchar(4000)
SET @exe=''
SELECT @exe = @exe + txt + ' ' FROM @qw ORDER BY id
/* execute dynamic sql */
EXEC master..sp_executesql @exe
Et voici le résultat:
alt text http://www.damirsystems.com/dp_images/morepivot_result_01.png
pourrait marquer une réponse sur ce point pour les futurs visiteurs s'il vous plaît? – Tanner