Gestionnaire de fenêtres Visual Studio

Question

Existe-t-il un gestionnaire de fenêtres pour Visual Studio 2008 comme this one. Je l'ai vraiment aimé, et c'est tout ce que j'ai utilisé dans Visual Studio 2005 et vu quelque part, il est censé fonctionner dans Visual   Studio   2008, mais ce n'est pas le cas. Je l'ai essayé sur de nombreuses installations de Visual   Studio   2008, et il ne se souvient pas des paramètres. J'ai vraiment aimé pouvoir changer facilement la disposition des fenêtres rapidement. En ce moment, je viens d'importer et d'exporter manuellement les paramètres, mais ce n'est pas un processus instantané.

Que dois-je faire pour le faire fonctionner?

Answer 1

Vous devez contacter RW au CodePlex. Il prétend l'avoir travaillé dans Visual   Studio   2008. Découvrez this item.

Answer 2

Les macros suivantes peuvent faire l'affaire pour vous. J'ai fait votre WindowManager mentionné ci-dessus, en le recompilant pour travailler pour Visual   Studio 2008, mais je l'ai encore trouvé un peu floconneux. En outre, je n'utilise pas la fonctionnalité "Auto Apply Layouts" dans WindowManager, donc ces macros fonctionnent très bien pour moi, en passant du fonctionnement à double moniteur au travail sur ordinateur portable uniquement.

Sub DualMonitorConfiguration_Save() 
    SaveWindowConfiguration("Dual Monitor Layout") 
End Sub 

Sub DualMonitorConfiguration_Load() 
    LoadWindowConfiguration("Dual Monitor Layout") 
End Sub 

Sub LaptopOnlyConfiguration_Save() 
    SaveWindowConfiguration("Laptop Only Layout") 
End Sub 

Sub LaptopOnlyConfiguration_Load() 
    LoadWindowConfiguration("Laptop Only Layout") 
End Sub 

Private Sub SaveWindowConfiguration(ByVal configName As String) 
    Dim selectedConfig As WindowConfiguration 
    selectedConfig = FindWindowConfiguration(configName) 
    If selectedConfig Is Nothing Then 
     selectedConfig = DTE.WindowConfigurations.Add(configName) 
    End If 

    selectedConfig.Update() 
    DTE.StatusBar.Text = "Window configuration saved: " & configName 
End Sub 

Sub LoadWindowConfiguration(ByVal configName As String) 
    Dim selectedConfig As WindowConfiguration 
    selectedConfig = FindWindowConfiguration(configName) 
    If selectedConfig Is Nothing Then 
     MsgBox("Window Configuration """ & configName & """ not found.") 
    Else 
     selectedConfig.Apply() 
     DTE.StatusBar.Text = "Window configuration applied: " & configName 
    End If 
End Sub 

Private Function FindWindowConfiguration(ByVal name As String) As WindowConfiguration 
    Dim selectedLayout As WindowConfiguration 

    For Each config As WindowConfiguration In DTE.WindowConfigurations 
     If config.Name = name Then 
      Return config 
     End If 
    Next 

    Return Nothing 
End Function 

Answer 3

Votre question a été répondu à la très same page où vous lui avez demandé :-)

Pour la petite histoire:

Pour obtenir ce travail pour 2008, ajouter un nouveau HostApplication élément au fichier WindowManager2005.AddIn. Le fichier se trouve généralement dans "% APPDATA% \ Microsoft \ MSEnvShared \ Addins". Changer la version dans le nouvel élément être 9.0 (VS 2008) et il devrait fonctionner en 2008 et en 2005.

<HostApplication> 
    <Name>Microsoft Visual Studio</Name> 
    <Version>9.0</Version> 
</HostApplication> 

Answer 4

Vous pouvez consulter mon blog, Save and Change Tool Layout in Visual Studio, qui fournit la possibilité de lister et de changer la disposition des fenêtres.