Rechercher et remplacer MOTS ENTIER SEULEMENT

Question

Je cherche un moyen de rechercher et de remplacer les mots entiers seulement. Puisque les mots entiers dans mon cas peuvent être séparés non seulement par un espace mais.,;: /? etc. Je ne peux pas penser à un moyen efficace de coder ceci.

Fondamentalement, je cherche à faire quelque chose comme ça

replace([address], ***--list of separators, like .,;:/?--*** & [replacewhat] & ***--list of separators, like .,;:/?--*** ," " & [replacewith] & " ") 

Je ne sais pas comment passer une liste de séparateurs à la fois en cours d'exécution à la place une fonction Replace une fois pour chaque combinaison de séparateurs (qui combinés avec 300 mots que je remplace serait un nombre fou de requêtes)

Answer 1

Vous pouvez faire un remplacement avec une expression régulière en utilisant un modèle avec le marqueur \b (pour la limite de mot) avant et après le mot que vous voulez remplacer.

Public Function RegExpReplaceWord(ByVal strSource As String, _ 
    ByVal strFind As String, _ 
    ByVal strReplace As String) As String 
' Purpose : replace [strFind] with [strReplace] in [strSource] 
' Comment : [strFind] can be plain text or a regexp pattern; 
'    all occurences of [strFind] are replaced 
    ' early binding requires reference to Microsoft VBScript 
    ' Regular Expressions: 
    'Dim re As RegExp 
    'Set re = New RegExp 
    ' with late binding, no reference needed: 
    Dim re As Object 
    Set re = CreateObject("VBScript.RegExp") 

    re.Global = True 
    're.IgnoreCase = True ' <-- case insensitve 
    re.pattern = "\b" & strFind & "\b" 
    RegExpReplaceWord = re.Replace(strSource, strReplace) 
    Set re = Nothing 
End Function 

Comme écrit, la recherche est sensible à la casse. Si vous voulez insensible à la casse, activez cette ligne:

re.IgnoreCase = True 

Dans la fenêtre immédiate ...

? RegExpReplaceWord("one too three", "too", "two") 
one two three 
? RegExpReplaceWord("one tool three", "too", "two") 
one tool three 
? RegExpReplaceWord("one too() three", "too", "two") 
one two() three 
? RegExpReplaceWord("one too three", "to", "two") 
one too three 
? RegExpReplaceWord("one too three", "t..", "two") 
one two three 

... et pour votre gamme de délimiteurs ...

? RegExpReplaceWord("one.too.three", "too", "two") 
one.two.three 
? RegExpReplaceWord("one,too,three", "too", "two") 
one,two,three 
? RegExpReplaceWord("one;too;three", "too", "two") 
one;two;three 
? RegExpReplaceWord("one:too:three", "too", "two") 
one:two:three 
? RegExpReplaceWord("one/too/three", "too", "two") 
one/two/three 
? RegExpReplaceWord("one?too?three", "too", "two") 
one?two?three 
? RegExpReplaceWord("one--too--three", "too", "two") 
one--two--three 
? RegExpReplaceWord("one***too***three", "too", "two") 
one***two***three