Copier le format en utilisant VBA

Question

J'ai un script, un script très simple, qui fait partie d'un script beaucoup plus grand, et maintenant ce dernier bit me donne des problèmes et je ne sais pas pourquoi.

C'est la partie du script qui me pose problème.

Option Explicit 


Sub Test() 

    Dim wsJL As Worksheet 'Jobs List 
    Dim lastrow As Long  
    Set wsJL = Sheets("Jobs List") 

    lastrow = wsJL.Range("B" & Rows.Count).End(xlUp).Row 
    wsJL.Range("B3:N3").Copy 
    wsJL.Range("B4:N" & lastrow).PasteSpecial xlPasteFormats 

End Sub 

Voici le classeur.

https://dl.dropbox.com/u/3327208/Excel/format.xlsm

Pour autant que je peux dire ce que je fais ne devrait pas se produire. Ce qui se passe est qu'il écrase tout, au lieu de remplacer le format par ce qui a été copié à l'origine.

Quelqu'un peut-il s'il vous plaît tenter de reproduire thisand me dire où est mon erreur?

Merci.

Answer 1

Vous pouvez faire la même chose sans copier-coller. Il nécessite un peu plus de code, mais n'utilise pas le presse-papiers et ne sélectionne rien sur votre feuille.

Il fonctionne considérablement plus rapidement. Je serais curieux de savoir si cela fonctionne mieux sur votre ordinateur de travail que ce que vous avez déjà essayé.

Essayez ceci:

Sub WriteInsteadOfCopyFormatting() 

    Dim wsJL As Worksheet 'Jobs List 
    Dim rng As Range ' Columns B through N 
    Dim dateRng As Range ' Column F 
    Dim numbersRng As Range ' Columns J through L 
    Dim NCMRRng As Range ' Column M 

    Dim lastRow As Long 
    Dim firstCopyRow As Long 

    Set wsJL = Sheets("Jobs List") 

    lastRow = wsJL.Range("B" & Rows.Count).End(xlUp).Row 
    firstCopyRow = 4 
    Set rng = wsJL.Range("B" & firstCopyRow & ":N" & lastRow) 
    Set dateRng = wsJL.Range("F" & firstCopyRow & ":F" & lastRow) 
    Set numbersRng = wsJL.Range("J" & firstCopyRow & ":J" & lastRow) 
    Set NCMRRng = wsJL.Range("M" & firstCopyRow & ":M" & lastRow) 

    With rng 
     .Interior.Color = 16777215 
     .Font.Name = "Calibri" 
     .Font.Size = 11 
     .Font.Color = vbBlack 
     .BorderAround Weight:=xlThin, Color:=vbBlack 
    End With 
    With rng.Borders(xlInsideVertical) 
     .Weight = xlThin 
     .Color = vbBlack 
    End With 
    With rng.Borders(xlInsideHorizontal) 
     .Weight = xlThin 
     .Color = vbBlack 
    End With 

    dateRng.NumberFormat = "d/mm/yyyy" 
    numbersRng.NumberFormat = "#,##0" 
    NCMRRng.NumberFormat = "0######" 

End Sub