Liste dynamique de sélection dans une autre dynamique dans Mathematica

Question

Construire sur la solution proposée par Bélisaire en "Manipulate custom Tabular".

• Tenir compte de la fonction suivante pour créer une représentation personnalisée tabulaires:

  DataSampleXX[data_, linesNumber_, columnsList_, color1_, color2_, color3_] := 
  
  Grid[ 
  Join[ 
      {columnsList}, {Map[Rotate[Text[#], 90 Degree] &, 
       data[[1, columnsList]]]}, data[[2 ;; linesNumber, columnsList]]], 
  Background -> {{{{color1, color2}}, {1 -> color3}}}, 
  Dividers -> {All, {1 -> True, 2 -> True, 3 -> True, 0 -> True}}, 
  ItemSize -> {1 -> Automatic, Automatic}, 
  Alignment -> Top, 
  Frame  -> True, 
  FrameStyle -> Thickness[2], 
  ItemStyle -> {Automatic, 
  Automatic, {{1, 1}, 
  {1, Length[data]}} -> Directive[FontSize -> 15, Black, Bold]} 
  ]; 
  

• Et les données suivantes:

  soData = {{"col1", "col2", "col3", "col4", "col5", "col6", "col7", 
        "col8", "col9", "col10"}, Range[1, 10], Range[11, 20], 
        Range[21, 30], Range[31, 40]} 
  
  
  With[ 
      {columnsList = {1, 3}, 
       data = soData, 
       linesNumber = 3, 
       color1 = LightBlue, 
       color2 = LightRed, 
       color3 = LightGray}, 
       DataSampleXX[data, linesNumber, columnsList, color1, color2, color3]] 
  

• Je voudrais intégrer la dynamique suivante pour alimenter l'argument columnsList de la fonction DataSampleXX.

  Manipulate[Sort@Join[Sequence @@ {a, b}], 
        Evaluate[Sequence @@ MapThread[{{#1, {}, ""}, #2, 
        ControlType -> TogglerBar} &, {{a, b}, 
        Partition[Rule @@@ Transpose[{Range[10], soData[[1]]}], 5]}]], 
        ControlPlacement -> Top] 
  

• Cela devrait me permettre de choisir dynamiquement les colonnes (VS une gamme de colonne dans ma question précédente) à afficher à l'aide DataSampleXX mais je figure encore Can`t comment fusionner les 2 mécanismes.

Answer 1

Qu'est-ce que vous voulez faire quelques trucs a besoin.

Par exemple:

Maipulate[ f[ Array[ a, exp], ...], ...] 

et constructions similaires ne fonctionnent pas (et il est expliqué dans la documentation), parce que le a[_] ne sont pas explicitement dans l'expression, donc il est difficile d'avoir un nombre variable de contrôles . La solution que je trouve est:

Manipulate[ f[#,...], ... ] & @ Array[a, exp] 

Autre problème est que la construction

Control@(.#.) &/@ _controls_ 

ne permet pas en soi deux partition dimensions, donc nous devons utiliser les deux options @ Control de syntaxe (@ Control et {...}), ce qui n'est pas documenté.

Autres nuisances que vous pouvez trouver dans le code ci-dessous.

Alors:

soData = {{"col01", "col02", "col03", "col04", "col05", "col06", 
      "col07", "col08", "col09", "col10"}, 
      Range[1, 10], Range[11, 20], Range[21, 30], Range[31, 40]}; 
perRow = 5; 
colsel = (# -> Graphics[{#, Disk[]}, ImageSize -> 15]) &/@ColorData[1, "ColorList"]; 
s[x_] := Style[x, Black, Bold, 12]; 
ct = ControlType -> PopupMenu; 

Manipulate[ 
    DataSampleXX[soData, linesNumber, Sort@Join[Sequence @@ #], color1, 
                   color2, color3], 
    Row[ 
    {Column[ 
     {Control@{{linesNumber, 2, s@"Lines"}, 
     Range[2, Length@soData[[All, 1]] - 1], ct}}], 
     Spacer[20], 
    Column[ 
     {Control@{{color1, colsel[[1, 1]], s@"Color 1"}, colsel, ct}, 
     Control@{{color2, colsel[[2, 1]], s@"Color 2"}, colsel, ct}, 
     Control@{{color3, colsel[[3, 1]], s@"Color 3"}, colsel, ct}}]}], 
    Evaluate[ 
    Sequence @@ 
    MapThread[{{#1, {}, ""}, #2, ControlType -> TogglerBar} &, 
     {#, Partition[Rule @@@ Transpose[{Range[10], soData[[1]]}], perRow]}]]] &@ 
Array[a, Length[soData[[1]]]/perRow]