Multple Trie dans un fichier texte

Question

Recherche d'une recherche non sensible à la casse en utilisant perl, donc si un "!" est détecté au début de la ligne, un nouveau tri commence (uniquement sur la section).

[test file] 
! Sort Section 
! 
a 
g 
r 
e 
! New Sort Section 
1 
2 
d 
3 
h 

devient,

[test file] 
! Sort Section 
! 
a 
e 
g 
r 
! New Sort Section 
1 
2 
3 
d 
h 

Answer 1

Un autre, en utilisant un fichier de sortie. Plus important encore, pas le chargement d'un fichier en mémoire:

use strict; 
use warnings; 
sub output { 
    my($lines, $fh) = @_; 
    return unless @$lines; 
    print $fh shift @$lines; # print first line 
    print $fh sort { lc $a cmp lc $b } @$lines; # print rest 
    return; 
} 
# ==== main ============================================================ 
my $filename = shift or die 'filename!'; 
my $outfn = "$filename.out"; 
die "output file $outfn already exists, aborting\n" if -e $outfn; 
# prereqs okay, set up input, output and sort buffer 
open my $fh, '<', $filename or die "open $filename: $!"; 
open my $fhout, '>', $outfn or die "open $outfn: $!"; 
my $current = []; 
# process data 
while (<$fh>) { 
    if (m/^!/) { 
     output $current, $fhout; 
     $current = [ $_ ]; 
    } 
    else { 
     push @$current, $_; 
    } 
} 
output $current, $fhout; 
close $fhout; 
close $fh; 

Answer 2

est ici une façon de le faire:

use strict; 
use warnings; 
my $filename = shift or die 'filename!'; 
my @sections; 
my $current; 
# input 
open my $fh, '<', $filename or die "open $filename: $!"; 
while (<$fh>) { 
    if (m/^!/) { 
     $current = [ $_ ]; 
     push @sections, $current; 
    } 
    else { 
     push @$current, $_; 
    } 
} 
close $fh; 
# output 
for (@sections) { 
    print shift @$_; # print first line 
    print sort @$_; # print rest 
}