En Perl, comment puis-je joindre des éléments d'un tableau après avoir entouré chaque élément entre parenthèses?

Question

J'essayais de joindre des éléments d'un tableau Perl.

@array=('a','b','c','d','e'); 
$string=join(']',@array); 

me donnera

$string="a]b]c]d]e"; 

Y at-il de toute façon je peux obtenir rapidement

$string="[a][b][c][d][e]"; 

?

Answer 1

Une autre façon de le faire, en utilisant sprintf.

my $str = sprintf '[%s]' x @array, @array; 

Answer 2

Peut-être:

{ 
    local $" = "]["; 
    my @array = qw/a b c d e/; 
    print "[@array]"; 
} 

Bien que vous devriez probablement:

print "[" . join("][", @array) . "]"; 

:-) Bonne codage

Answer 3

#!/usr/bin/perl 
use strict; use warnings; 

local $" = ''; 
my $x = qq|@{[ map "[$_]", qw(a b c d e) ]}|; 

Vous pouvez également généraliser un peu:

#!/usr/bin/perl 
use strict; use warnings; 

my @array = 'a' .. 'e'; 

print decorate_join(make_decorator('[', ']'), \@array), "\n"; 

sub decorate_join { 
    my ($decorator, $array) = @_; 
    return join '' => map $decorator->($_), @$array; 
} 

sub make_decorator { 
    my ($left, $right) = @_; 
    return sub { sprintf "%s%s%s", $left, $_[0], $right }; 
} 

Answer 4

Voici deux options:

#!/usr/bin/perl 

use strict; 
use warnings; 

my @array = 'a' .. 'e'; 
my $string = join('', map { "[$_]" } @array); 
my $string1 = '[' . join('][', @array) . ']';