GNU Prolog - rechercher une liste de faits

Question

Je dois avoir un pet de cerveau ou quelque chose, mais je n'arrive pas à trouver une solution à cela.

Si vous avez une liste de faits tels que:

%country(country, population, capital) 
country(sweden, 8823, stockholm). 
country(usa, 221000, washington). 
country(france, 56000, paris). 
country(denmark, 3400, copenhagen). 

%city(city, country, population) 
city(lund, sweden, 88). 
city(new_york, usa, 5000). 
city(paris, usa, 1). 
city(copenhagen, denmark, 1200). 
city(aarhus, denmark, 330). 
city(odense, denmark, 120). 
city(stockholm, sweden, 350). 
city(washington, usa, 3400). 
city(paris, france, 2000). 
city(marseilles, france, 1000). 

Je veux trouver la deuxième plus grande ville peuplée, qui dans ce cas serait Washington, Etats-Unis avec 3400 personnes. Comment serais-tu capable de faire ça?

Merci.

Answer 1

Version légèrement plus courte d'une excellente réponse @ Sharky:

second_largest_city(Second) :- 
    setof(Size/City, Country^city(City,Country,Size), Cities), 
    append(_, [_/Second, _], Cities). 

setof combine findall et sort. Nous collectons Size/City paires afin qu'elles trient automatiquement la taille. La construction X^Goal introduit une variable quantifiée existentiellement X (comme ∃ x dans la logique du premier ordre).

Answer 2

Essayez ceci pour la taille:

second_largest_city(City) :- 
    findall(Size, city(_, _, Size), Sizes), 
    sort(Sizes, SortedSizes), 
    append(_, [Size2, _], SortedSizes), 
    city(City, _Country, Size2). 

Explication: Le findall/3 trouve la taille de tous city/3 faits, qui sont classés en ordre croissant par ordre sort/2 avec doublons supprimés. L'appel au modèle append/3 correspond à la partition de la liste triée SortedSizes en deux parties; une liste de n'importe quelle taille (_) et un reste de longueur deux ([Size2, _]) - cela lie la variable Size2 à la deuxième plus grande taille de la ville de city/3 faits. Enfin, toutes les villes de cette taille sont situées parmi city/3 faits, et sont liées à la sortie.

Note: Cela ne fonctionnera pas correctement en général si votre intégré pour sort/2n'a pas supprimer les doublons, car cela laisse la possibilité que city/3 faits avec plus d'un maximum égal renverront au maximum (plus grand) seulement. Cette implémentation utilisant append/3 pour rechercher l'avant-dernier élément de la liste triée des tailles suppose également sort/2 les numéros triés dans l'ordre croissant. Enfin, notez enfin que cela échouera complètement s'il y a moins de deux faits - mais cela est probablement correct, étant donné que le prédicat cherche la «deuxième plus grande» ville, et à strictement parler, il n'y aurait pas de un à moins qu'il y ait en effet au moins deux villes dans la DB avec des tailles différentes. Si c'est un problème, vous pouvez simplement écrire plus de clauses pour second_largest_city/1 pour gérer un tel cas.