XQuery: problème d'espace de noms dans les fonctions locales

Question

J'ai le problème suivant avec ma fonction locale.

La fonction suivante:

declare function local:exp($w as node()) as element()* { 
for $e in ($w/e) 
let $exp:= QName ("myns", "real") 
return 
    element {$exp}{ 
    attribute resource {$e/@lang} 
    } 
}; 

génère ce xml:

<real xmlns="myns" resource="eng"/> 

Ce qui a vraiment besoin est:

<myns:real rdf:resource="lang"/> 

Comment puis-je achive cela?

1. Comment puis-je résoudre le problème?
2. Comment puis-je ajouter "rdf" comme NS pour l'attribut de ressource.

Merci d'avance.

Answer 1

Vous pouvez attribuer le préfixe à la QName comme si:

let $exp:= QName ("urn:my-namespace", "myns:real") 

Probablement la meilleure façon de résoudre ce problème est de déclarer ces espaces de noms dans votre requête et simplement les consulter par préfixe:

declare namespace rdf="http://www.w3.org/1999/02/22-rdf-syntax-ns#"; 
declare namespace myns="urn:my-namespace"; 

declare function local:exp($w as node()) as element()* { 
for $e in $w/e 
return 
    element myns:real { 
    attribute rdf:resource {$e/@lang} 
    } 
}; 

Notez que vous pouvez simplifier votre fonction à l'aide des constructeurs directs:

declare function local:exp($w as node()) as element()* { 
for $e in $w/e 
return <myns:real rdf:resource="{$e/@lang}" /> 
};