Trouver la différence entre 2 dates dans xslt

Question

Existe-t-il une façon moins clémente de trouver la différence en jours entre deux dates dans xslt? Si oui pouvez-vous me pointer dans la bonne direction. Je reçois des dates au format mm/jj/aaaa.

Answer 1

Utilisez XSLT 2.0 (XPath 2.0) pour cette:

<xsl:stylesheet version="2.0" 
    xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
    xmlns:xs="http://www.w3.org/2001/XMLSchema" 
    xmlns:my="my:my"> 
    <xsl:output omit-xml-declaration="yes" indent="yes"/> 

<xsl:template match="/"> 
    <xsl:variable name="vDate1" 
     select="my:dateFromUsDate(/*/d1)"/> 
    <xsl:variable name="vDate2" 
     select="my:dateFromUsDate(/*/d2)"/> 

    <xsl:sequence select= 
    "($vDate1 - $vDate2) div xs:dayTimeDuration('P1D')"/> 
</xsl:template> 

<xsl:function name="my:dateFromUsDate" as="xs:date"> 
    <xsl:param name="pUsDate" as="xs:string"/> 

    <xsl:sequence select= 
    "xs:date(concat(substring($pUsDate,7,4), 
        '-', 
        substring($pUsDate,1,2), 
        '-', 
        substring($pUsDate,4,2) 
       ) 
     ) 
    "/> 
</xsl:function> 
</xsl:stylesheet> 

lorsque cette transformation est appliquée sur le document XML suivant:

<t> 
<d1>04/06/2011</d1> 
<d2>01/11/2010</d2> 
</t> 

le résultat recherché, correct (la différence est de 450 jours) est produit:

450 

Answer 2

Une alternative plus agréable (et plus courte) pour XSLT 1.0 est de calculer les dates juliennes équivalentes et de les soustraire.

Modèle:

<xsl:template name="calculate-julian-day"> 
    <xsl:param name="year"/> 
    <xsl:param name="month"/> 
    <xsl:param name="day"/> 

    <xsl:variable name="a" select="floor((14 - $month) div 12)"/> 
    <xsl:variable name="y" select="$year + 4800 - $a"/> 
    <xsl:variable name="m" select="$month + 12 * $a - 3"/> 

    <xsl:value-of select="$day + floor((153 * $m + 2) div 5) + $y * 365 + floor($y div 4) - floor($y div 100) + floor($y div 400) - 32045"/> 

Utilisation:

<xsl:variable name="dateInv" select="'20120406'" /> 
<xsl:call-template name="calculate-julian-day"> 
    <xsl:with-param name="year" select="substring($date,1,4)"/> 
    <xsl:with-param name="month" select="substring($date,5,2)"/> 
    <xsl:with-param name="day" select="substring($date,7,2)"/> 
</xsl:call-template> 

Répétez l'opération pour la deuxième date et vous aurez deux entiers. Ensuite, il suffit de les soustraire.

Answer 3

Cela pourrait se faire facilement en utilisant l'expression suivante:

days-from-duration(xs:date('yyyy-MM-dd')-xs:date('yyyy-MM-dd')) 

Par exemple:

days-from-duration(xs:date('2012-06-30')-xs:date('2012-06-18')) 

donnera suite à