Comment puis-je rechercher et remplacer un nombre spécifique de fois dans une chaîne en Perl?

Question

Comment puis-je rechercher et remplacer une correspondance avec un nombre spécifique de fois en utilisant s///;. Par exemple:

$string="abcabdaaa"; 

Je veux remplacer a avec i dans $string n fois. Comment puis je faire ça? n est un nombre entier fourni par l'utilisateur.

Answer 1

Je ne suis au courant d'aucun drapeau qui ferait cela. Je voudrais simplement utiliser une boucle:

for (my $i = 0; $i < $n; $i++) 
{ 
    $string =~ s/a/i/; 
} 

Answer 2

seulement $ substituez n fois:

$string =~ s/a/i/ for 1..$n; 

Cela fera.
solution plus générale serait substitution globale avec contre:

my $i = 0; # count the substitutions made 
$string =~ s/(a)/ ++$i > $n ? $1 : "i" /ge; 

Answer 3

vous pouvez essayer ceci:

$str1=join('i',split(/a/,$str,$n)); 

Answer 4

La réponse simple ne probablement ne veux pas que vous voulez.

my $str = 'aaaa'; 
$str =~ s/a/a_/ for 1..2; 
print $str, "\n"; # a__aaa. But you want a_a_aa, right? 

Vous devez compter les remplacements vous, et agir en conséquence:

$str = 'aaaa'; 
my $n = 0; 
$str =~ s/(a)/ ++$n > 2 ? $1 : 'a_' /ge; 
print $str, "\n"; 

Voir la FAQ, How do I change the Nth occurrence of something? des exemples connexes.

Answer 5

En utilisant

sub substitute_n { 
    my $n = shift; 
    my $pattern = shift; 
    my $replace = shift; 
    local $_ = shift; 

    my $i = 1; 
    s{($pattern)} { 
    $i++ <= $n ? eval qq{"$replace"} : $1; 
    }ge; 

    $_; 
} 

Vous pouvez alors écrire

my $s = "***ab***c"; 

print "[", substitute_n(2, qr/\*/, '$1\n', $s), "]\n"; 

pour obtenir la sortie suivante:

[* 
* 
*ab***c]

Answer 6

Voici une façon de le faire sur la base du commentaire que vous avez fait à eugene y's answer

#!/usr/bin/perl 

use strict; use warnings; 

my $string = '***ab***c'; 
my $n = 3; 

1 while $n -- and $string =~ s/\*([^\n])/*\n$1/; 

print "$string\n"; 

Sortie:

* 
* 
* 
ab***c