La meilleure façon de coder ce, chaîne à la carte de conversion en Groovy

Question

J'ai une chaîne comme

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 

Je veux le convertir en une carte

["session", 234567893egshdjchasd] 
["userId", 12345673456] 
["timeout", 1800000] 

Ceci est la façon actuelle que je fais il,

def map = [:] 

data.splitEachLine("&"){ 

    it.each{ x -> 

    def object = x.split("=") 
    map.put(object[0], object[1]) 

    } 

} 

Cela fonctionne, mais y at-il un moyen plus efficace?

Answer 1

Je ne sais pas pense que cela irait plus vite, mais il ne lui-même suggère en termes de parcimonie syntaxique:

def data = 'session=234567893egshdjchasd&userId=12345673456&timeOut=1800000' 
def result = data.split('&').inject([:]) { map, token -> 
    token.split('=').with { map[it[0]] = it[1] } 
    map 
} 

Personnellement, j'aime la réponse de Don pour une meilleure lisibilité et la maintenabilité, mais selon le contexte, cela peut être approprié.

Édition: Il s'agit en fait d'un doublage reformaté.

Answer 2

Je ne sais pas si cela est plus efficace, mais à mes yeux, il est un peu plus simple (YMMV)

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 
def map = [:] 

data.split("&").each {param -> 
    def nameAndValue = param.split("=") 
    map[nameAndValue[0]] = nameAndValue[1] 
} 

Answer 3

Si vous êtes à la recherche d'expressions régulières sont efficaces, où il est:

def data = "session=234567893egshdjchasd&userId=12345673456&timeOut=1800000" 
def map = [:] 
data.findAll(/([^&=]+)=([^&]+)/) { full, name, value -> map[name] = value } 

println map 

impressions:

[session:234567893egshdjchasd, userId:12345673456, timeOut:1800000] 

Si vous n'êtes pas familier avec les expressions régulières, cela peut paraître un peu étranger, mais ce n'est vraiment pas si compliqué. Il a juste deux (groupes), le premier groupe est n'importe quel caractère mais un "&" ou un "=". Le deuxième groupe est n'importe quel caractère en plus d'un "=". Les groupes de capture sont de chaque côté d'un "=".

Answer 4

Si vous êtes un contrôleur de Grails, alors c'est agréable et simple:

GrailsParameterMap map = new GrailsParameterMap(request) 

http://grails.org/doc/latest/api/org/codehaus/groovy/grails/web/servlet/mvc/GrailsParameterMap.html

Answer 5

Si vous utilisez Grails, la meilleure façon que je trouve est WebUtils la fonction fromQueryString.

https://grails.github.io/grails-doc/2.0.x/api/org/codehaus/groovy/grails/web/util/WebUtils.html

Answer 6

Voici mon effort, initialisant et remplit la carte en une seule fois, et évite la méthode d'injection que je trouve personnellement difficile à suivre: -

def map = data.split('&').collectEntries { 
     def kvp = it.split('=').collect { string -> 
      string = string.trim() 
      return string 
    } 
    [(kvp[0]): kvp.size() > 1 ? kvp[1] ?: '' : ''] 
    // the null check is almost certainly overkill so you could use :- 
    // [(kvp[0]): kvp.size() > 1 ? kvp[1] : ''] 
    // this just checks that a value was found and inserts an empty string instead of null 
} 

Answer 7

Après quelques recherches, « collectEntries() "est la chose magique à utiliser, elle crée un élément de carte. Travaillez comme "collect()" qui crée une liste.Donc, étant donné

def params = "a1=b1&a2=b2&a3&a4=&a5=x=y" 

le one-liner est

map = params.tokenize("&").collectEntries{ 
      it.split("=",2).with{ 
       [ (it[0]): (it.size()<2) ? null : it[1] ?: null ] 
      } 
     } 

qui crée

map = [a1:b1, a2:b2, a3:null, a4:null, a5:x=y] 

Selon la façon dont vous voulez gérer les cas "a3" et "a4 =" vous pouvez également utiliser une version légèrement plus courte

... 
[ (it[0]): (it.size()<2) ? null : it[1] ] 
... 

et puis vous obtenez ceci:

map = [a1:b1, a2:b2, a3:null, a4:, a5:x=y]