Le premier mot de PascalCase en minuscules

Question

J'ai une chaîne qui contient du texte dans PascalCase et je dois extraire premier mot et le convertir en minuscules:

assert firstWord('PmdExtension') == 'pmd' 
assert firstWord('PMDExtension') == 'p' 
assert firstWord('Pmd') == 'pmd' 
assert firstWord('CodeQualityExtension') == 'code' 

static String firstWord(String word) { 
    return '???' 
} 

Concentrons uniquement sur les identifiants de PascalCase valides (sans autres caractères, chiffres et toujours en commençant par la lettre majuscule).

Quelle serait la solution simple et propre à mon problème?

J'ai essayé

word.split(/[A-Z]/).first().join(' ') 

mais il supprime toutes les lettres en majuscules, alors que je dois les conserver.

Answer 1

Quelque chose comme:

static String firstWord(String word) { 
    return word[0].toLowerCase()+word.split(['A'..'Z'].join('|'))[1] 
} 

Answer 2

La méthode inject peut être utilisé pour accumuler des caractères jusqu'à la deuxième lettre majuscule est rencontré:

def firstWord(String word) { 
    def numCapsObserved = 0 
    def initVal = "" 

    word.inject(initVal, { val, letter -> 
     def result = val 
     if (letter ==~ /[A-Z]/) { numCapsObserved++ } 

     if (numCapsObserved < 2) { 
      result += letter.toLowerCase() 
     } 
     return result 
    }) 
} 

assert firstWord('PmdExtension') == 'pmd' 
assert firstWord('PMDExtension') == 'p' 
assert firstWord('Pmd') == 'pmd' 
assert firstWord('CodeQualityExtension') == 'code' 

Answer 3

assert firstWord('PmdExtension') == 'pmd' 
assert firstWord('PMDExtension') == 'p' 
assert firstWord('Pmd') == 'pmd' 
assert firstWord('CodeQualityExtension') == 'code' 
assert firstWord('') == '' 
assert firstWord(null) == '' 

static String firstWord(String word) { 
    word ? word.split(/(?=\p{Lu})/)[0].toLowerCase() : '' 

    // A verbose way would be as below (omitting the null check for brevity) 
    // word[0].toLowerCase() + word[1..-1].takeWhile { Character.isLowerCase(it) } 
} 

Answer 4

L'opérateur trouve Groovy (=~) semble faire le travail bien:

static String firstWord(String word) { 
    word ? (word =~ /[A-Z][a-z]*/)[0].toLowerCase() : '' 
}