Comment envoyer des données de publication et d'en-tête avec Chromium?

Question

Je tente de convertir du code de TWebBrowser en Chrome mais je n'arrive pas à trouver comment envoyer des données de post et d'en-tête avec une requête HTTP.

Voici la fonctionnalité TWebBrowser que j'essaie de mettre en œuvre.

var 
VHeader, PostData: OleVariant; 


PostData := VarArrayCreate([0, Length(XMLString) - 1], varByte) ;  
HeaderData := 'Content-Type: application/x-www-form-urlencoded'+ '\n'; 

WebBrowser1.Navigate(StrUrl,EmptyParam,EmptyParam,PostData,VHeader); 

Comment faire l'équivalent avec Chromium?

Answer 1

En raison d'une documentation manquante pour Delphi Chromium Embedded, je ferai référence aux exigences requises pour l'envoi de requêtes Web pour la version C++ de CEF. Donc, vous devez utiliser la méthode LoadRequest pour envoyer des requêtes dans Chromium. Pour l'utiliser, vous avez besoin de l'instance d'objet de la classe d'objet de requête CefRequest avec les objets HeaderMap et CefPostData pour l'en-tête de requête et la spécification de données.

Développant Henri Gourvest (auteur de l'emballage CEF Delphi) exemple de this thread, vous pouvez à Delphes essayer quelque chose comme le pseudo-code suivant:

uses 
    ceflib; 

function CreateField(const AValue: AnsiString): ICefPostDataElement; 
begin 
    Result := TCefPostDataElementRef.New; 
    Result.SetToBytes(Length(AValue), PAnsiChar(AValue)); 
end; 

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 

    Request := TCefRequestRef.New; 
    Request.Flags := WUR_FLAG_NONE; 
    Request.Assign('http://example.com/', 'POST', Data, Header); 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end; 

La même chose devrait faire une autre version du code ci-dessus :

procedure TForm1.Button1Click(Sender: TObject); 
var 
    Header: ICefStringMultimap; 
    Data: ICefPostData; 
    Request: ICefRequest; 
begin 
    Request := TCefRequestRef.New; 
    Request.Url := 'http://example.com/'; 
    Request.Method := 'POST'; 
    Request.Flags := WUR_FLAG_NONE; 

    Header := TCefStringMultimapOwn.Create; 
    Header.Append('Content-Type', 'application/x-www-form-urlencoded'); 
    Request.SetHeaderMap(Header); 

    Data := TCefPostDataRef.New; 
    Data.AddElement(CreateField('Data.id=27')); 
    Data.AddElement(CreateField('&Data.title=title')); 
    Data.AddElement(CreateField('&Data.body=body')); 
    Request.PostData := Data; 

    Chromium1.Browser.MainFrame.LoadRequest(Request); 
end;