Capitaliser la première lettre d'un jeu de résultats

Question

J'ai ce code SPARQL qui est destiné à travailler sur Wikidata:

SELECT 
    ?game 
    (group_concat(distinct  ?gameLabel ; separator = ", ") AS  ?gameLabels) 
    (group_concat(distinct  ?genreLabel ; separator = ", ") AS  ?genreLabels) 
    WHERE { 
    ?game wdt:P31 wd:Q7889; 
    wdt:P136 wd:Q744038. 
    OPTIONAL {?game wdt:P136  ?genre} 
    SERVICE wikibase:label { 
     bd:serviceParam wikibase:language "en". 
      ?game rdfs:label  ?gameLabel. 
      ?genre rdfs:label  ?genreLabel. 
    } 
    } 
GROUP BY $game 
ORDER BY ASC (?gameLabels) 

Vous pouvez tester le code ici:

https://query.wikidata.org/

Supposons que ?genreLabel est toujours en minuscules par défaut. Comment puis-je mettre en majuscule la première lettre de chaque valeur renvoyée? Merci.

Answer 1

C'est le point où les choses se compliquent avec l'étiquette magique SERVICE Wikidata parce que vous ne pouvez pas les utiliser dans des pièces de BIND - ou moins, je ne sais pas comment:

SELECT 
    ?game 
    (group_concat(distinct  ?gameLabel ; separator = ", ") AS  ?gameLabels) 
    (group_concat(distinct  ?genreL ; separator = ", ") AS  ?genreLabels) 

    WHERE { 
    ?game wdt:P31 wd:Q7889 ; 
      wdt:P136 wd:Q744038 . 
    OPTIONAL { 
     ?game wdt:P136  ?genre. 
     ?genre rdfs:label ?gL. 
     FILTER(LANGMATCHES(LANG(?gL), "en")) 
    } 
    BIND(CONCAT(UCASE(SUBSTR(?gL, 1, 1)), SUBSTR(?gL, 2)) as ?genreL) 

    SERVICE wikibase:label { 
     bd:serviceParam wikibase:language "en". 
      ?game rdfs:label  ?gameLabel. 
    } 

    } 
GROUP BY ?game 
ORDER BY ASC (?gameLabels) 

L'idée est que suit:

• prendre le premier caractère de l'étiquette: SUBSTR(?gL, 1, 1)
• appliquent l'opérateur de majuscules sur elle: UCASE(SUBSTR(?gL, 1, 1))
• prendre toute la chaîne à partir du second caractère: SUBSTR(?gL, 2))
• concaténer les deux parties: CONCAT(UCASE(SUBSTR(?gL, 1, 1)), SUBSTR(?gL, 2))

note, à un moment donné, il pourrait être plus facile de faire la modification chaîne et le style du côté client ...