Face ORA-01722: Erreur de numéro incorrect lors de la sélection des données à partir d'une table

Question

CREATE OR REPLACE FUNCTION XXCHR_FNC(
    P_EMP_ID   IN NUMBER, 
    P_COLUMN_NAME IN VARCHAR2 
) RETURN VARCHAR2 
IS 
    lv_dyn_sql VARCHAR2(2000):= NULL; 
    lv_return_val VARCHAR2(200); 
BEGIN 
    lv_dyn_sql:='SELECT :2 FROM thirty_days ' 
       || 'WHERE salesrep_id=:1'; 

    EXECUTE IMMEDIATE lv_dyn_sql INTO lv_return_val 
    USING P_EMP_ID,P_COLUMN_NAME; 

    RETURN(lv_return_val); 
EXCEPTION 
    WHEN OTHERS THEN 
    dbms_output.put_line('Returning Error : '||SQLERRM); 
    RETURN (SQLERRM); 
END XXCHR_FNC; 

Answer 1

Vous ne pouvez pas passer un nom de colonne comme une variable de liaison - si vous le faites vous retournerez le nom de colonne comme une chaîne plutôt littérale que d'obtenir la valeur de la colonne. Vous devez utiliser la concaténation sur la chaîne SQL:

CREATE OR REPLACE FUNCTION XXCHR_FNC(
    P_EMP_ID   IN NUMBER, 
    P_COLUMN_NAME IN VARCHAR2 
) RETURN VARCHAR2 
IS 
    lv_return_val VARCHAR2(200); 
BEGIN 
    EXECUTE IMMEDIATE 
    'SELECT ' || P_COLUMN_NAME || ' FROM thirty_days WHERE salesrep_id=:1' 
    INTO lv_return_val 
    USING P_EMP_ID; 

    RETURN lv_return_val; 
EXCEPTION 
    WHEN OTHERS THEN 
    dbms_output.put_line('Returning Error : '||SQLERRM); 
    RETURN SQLERRM; 
END XXCHR_FNC; 
/

Test:

CREATE TABLE thirty_days (
    salesrep_id NUMBER(8,0), 
    a VARCHAR2(20), 
    b VARCHAR2(20), 
    c VARCHAR2(20), 
    d VARCHAR2(20) 
); 

INSERT INTO thirty_days VALUES(1, 'a', 'b', 'c', 'd'); 

Sortie:

SELECT xxchr_fnc(1, 'a') FROM DUAL; 

XXCHR_FNC(1,'A') 
---------------- 
a