Tri de groupes en Perl

Question

Je suis nouveau sur Perl et je suis bloqué par un problème de tri (probablement simple).

J'ai hérité du code Perl qui lit les lignes d'un fichier texte en trois tableaux 1D (x, y, z). J'aimerais pouvoir trier ces tableaux en utilisant l'une des dimensions comme clé et en réordonnant les deux autres dimensions.

Par exemple, si mon entrée est:

• @x = (1, 3, 2)
• @y = (11,13,12)
• @z = (21, 23,22)

et je sorte par x, je voudrais que le résultat soit:

• @x = (1, 2, 3)
• @y = (11,12,13) ​​
• @z = (21,22,23)

je puisse fusionner les trois tableaux 1-D en une matrice 2-D si cela fait vie Plus facile.

Answer 1

use strict; 
use warnings; 
use Data::Dumper; 

use List::Util qw(reduce); 

my @x = (1, 3, 2); 
my @y = (11, 13, 12); 
my @z = (21, 23, 22); 

my @combined = map { [ $x[$_], $y[$_], $z[$_] ] } 0 .. $#x; 
my @sorted = sort { $a->[0] <=> $b->[0] } @combined; 
my $split_ref = reduce { push @{$a->[$_]}, $b->[$_] for 0 .. $#$a; $a;} [[], [], []], @sorted; 

print Dumper \@combined; 
print Dumper \@sorted; 
print Dumper $split_ref; 

qui va essentiellement vous donner:

[ 
     [ 
     1, 
     2, 
     3 
     ], 
     [ 
     11, 
     12, 
     13 
     ], 
     [ 
     21, 
     22, 
     23 
     ] 
    ]; 

Answer 2

Do

@a = sort { $a <=> $b } @a; 

Voir aussi sort on perldoc.

Answer 3

La fusion peut en effet rendre la vie plus facile.

@sorted = sort { $a->[0] <=> $b->[0] } 
    ([$x[0], $y[0], $z[0]], [$x[1], $y[1], $z[1]], [$x[2], $y[2], $z[2]]); 

peut le faire. Vous ne voudrez bien sûr pas écrire tout cela à la main!

Answer 4

Si @x a la même taille que @y et @z, il n'est pas nécessaire de trier - Vous pouvez utiliser une tranche de tableau à la place!

use strict; 
use warnings; 
use 5.010; 

my @x = (1, 3, 2); 
my @y = (11,13,12); 
my @z = (21,23,22); 

say join ', ', @y; 
@y = @y[ map { $_ - 1 } @x ]; #We use map create a lists of the values of elements in @x, minus 1. 
say join ', ', @y; 

Bien sûr, si vous voulez juste trier par ordre numérique, puis en utilisant @x est superflue:

@y = sort { $a <=> $b } @y; 

Enfin, si vous voulez trier un nombre arbitraire de tableaux, vous pouvez créer un tableau de tableaux, ou passer une liste de références à un pour, ala

my @indexes = map { $_ - 1 } @x; 

for my $array_ref (\@x, \@y, \@z) { 
    @$array_ref = @{$array_ref}[@indexes]; 
} 

Answer 5

avoir un essai avec:

#!/usr/bin/perl 
use 5.10.1; 
use strict; 
use warnings; 
use Data::Dumper; 

my @x = (1, 3, 2); 
my @y = (11,13,12); 
my @z = (21,23,22); 

my (%y, %z); 

@y{@x} = @y; 
@z{@x} = @z; 

my @xs = sort @x; 
my @ys = @y{@xs}; 
my @zs = @z{@xs}; 
say Dumper \@xs,\@ys,\@zs; 

Sortie:

$VAR1 = [ 
      1, 
      2, 
      3 
     ]; 
$VAR2 = [ 
      11, 
      12, 
      13 
     ]; 
$VAR3 = [ 
      21, 
      22, 
      23 
     ]; 

Answer 6

fusion ensemble tous les tableaux ne sont pas nécessaires.Utilisez sort pour obtenir l'ordre d'index correct pour les éléments en @x:

@sort_by_x = sort { $x[$a] <=> $x[$b] } 0 .. $#x; # ==> (0, 2, 1) 

Appliquer ensuite que la commande d'index à tout autre tableau:

@x = @x[@sort_by_x]; 
@y = @y[@sort_by_x]; 
@z = @z[@sort_by_x];