La boucle est bloquée lors de l'utilisation de SET avec/P

Question

Comme certains le savent, je travaille sur un script pour collecter des informations sur un ordinateur pour accélérer le processus. Non, je suis coincé parce que je voulais écrire le résultat décodé dans un fichier texte sans le spammer avec de nouvelles lignes. Le problème est que dès que je veux faire ajouter le paramètre /p il s'arrête après le premier tour de décodage.

@echo offsure 
set list=89 86 51 84 49 55 52 49 52 49 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%X IN (%list%) DO (
    set /p temp=%%~nX 
    cmd /c exit !temp:~0,7! 
    set temp2=!=exitcodeAscii! 
    echo !temp2! 
) >> C:\TestConverters.txt 
Echo. >> C:\TestConverters.txt 
pause 

Voici le code source que j'utilise actuellement. Si je supprime le paramètre/p cela fonctionne parfaitement bien. Alors maintenant, je suis en train d'essayer d'améliorer le résultat du test que j'utilise dans le script pour avoir au moins ce petit truc déjà élaboré.

Answer 1

set /p temp=%%~nX demandera à l'utilisateur une variable nommée temp, présentant une invite de %%~nX. Probablement pas ce que tu veux.

Je suppose que vous voulez écrire !temp2! sans saut de ligne.
Oui il y a une astuce set /p pour le faire, mais a) vous l'avez utilisé au mauvais endroit et b) vous ne voulez pas que l'utilisateur entre quelque chose (qui mettra en pause votre script), mais prend la contribution de NUL à la place:

Remplacer

echo !temp2! 

avec

<nul set /p =!temp2! 

(et supprimer l'espace de fuite à la ligne précédente)

Après le commentaire de Compo, votre code peut être simplifié comme:

@echo off 
set list=89 86 51 84 49 55 52 49 52 49 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
(
    FOR %%X IN (%list%) DO (
    cmd /c exit %%X 
    <nul set /p =!=exitcodeAscii! 
) 
    echo. 
)>>C:\TestConverters.txt 
pause 

Answer 2

Ou vous pouvez essayer.

@echo off 
set list=89 86 51 84 49 55 52 49 52 49 
SETLOCAL ENABLEEXTENSIONS ENABLEDELAYEDEXPANSION 
FOR %%X IN (%list%) DO (
set temp=%%~nX 
cmd /c exit !temp:~0,7! 
set temp2=!=exitcodeAscii! 
<nul set /p =!temp2! 
) >> C:\BACKUPS\TestConverters.txt 
Echo. >> C:\BACKUPS\TestConverters.txt 
pause 

Answer 3

Un exemple rapide, si vous n'avez pas vraiment besoin d'utiliser SET/P:

@ECHO OFF 
SETLOCAL ENABLEDELAYEDEXPANSION 
SET "list=89 86 51 84 49 55 52 49 52 49" 
SET "variable=" 
FOR %%X IN (%list%) DO (CMD/C EXIT %%X 
    Set "variable=!variable!!=EXITCODEASCII!") 
IF DEFINED variable >"C:\TestConverters.txt" ECHO(%variable% 
PAUSE