Codage VBA - Génération de variable aléatoire

Question

Je souhaite écrire un code dans un fichier VBA Excel. J'ai préparé l'algorithme qui est montré ci-dessous, mais je ne sais pas exactement comment je vais l'écrire dans VBA:/ Quelqu'un peut-il m'aider avec cela?

1) Attribuer des valeurs initiales: le courant est 1, l'année est 0, le résultat est une chaîne vide.

2) Générer une variable aléatoire u à partir de U (0,1);

3) Si Current est 1 et u ≤ 0,23, attribuez 0 à Current. Si Current est 0 et u> 0,86, attribuez 1 à Current. Sinon, ne faites rien.

4) Augmenter l'année de 1. Ecrire le courant à la fin de la chaîne de résultat.

5) Si la valeur Année est inférieure à la cellule ("A2"), passez à l'étape (2). Sinon retour Résultat

Answer 1

Voici une UDF (fonction définie par l'utilisateur) qui peut être utilisé directement sur la feuille de calcul:

Function Chain(years As Long) As String 
    Dim i As Long, result As String 
    Dim u As Single 
    Dim current As Long 

    Randomize 
    Application.Volatile 

    current = 1 
    For i = 1 To years 
     u = Rnd() 
     If (current = 1 And u <= 0.23) Or (current = 0 And u > 0.86) Then 
      current = 1 - current 
     End If 
     result = result & current 
    Next i 
    Chain = result 
End Function 

year est juste un compteur et votre algorithme décrit en effet une simple boucle for. En VBA, il est plus idiomatique de faire une boucle de 1 à n que de 0 à n-1 pour un simple compteur - bien que ce soit principalement une question de goût. En outre - j'ai changé year à i pour empêcher l'observation accidentelle de la fonction intégrée year()

VBA a des valeurs par défaut pour les variables naturelles, donc je ne l'ai pas besoin d'initialiser explicitement result.

J'ai fait la fonction volatile - donc il recalcule à chaque fois que la feuille de calcul. Cela correspond à RAND() fonctionne dans Excel. Si vous ne le souhaitez pas, supprimez la ligne Application.Volatile.

Une capture d'écran:

Answer 2

Cela se traduit par votre anglais VBA

Sub Jona() 
    Dim Current As Long, Yearr As Long 
    Dim u As Double, Result As String 

    Current = 1 
    Yearr = 0 

    While Yearr < Range("A2").Value 
     u = Rnd() 
     If Current = 1 And u <= 0.23 Then 
     Current = 0 
     ElseIf Current = 0 And u > 0.86 Then 
     Current = 1 
     End If 
     Yearr = Yearr + 1 
     Result = Result & Current 
    Wend 

    MsgBox Result 
End Sub