Différence entre deux ensembles de données dans SQL Server 2000

Question

J'essaie de déterminer la différence entre les clients facturés au cours des trois derniers mois et l'ensemble de la clientèle. Je suis en mesure de calculer les clients qui ont été facturés en utilisant le SQL

DECLARE @DateFrom AS DATETIME 
SET @DateFrom = 
    CONVERT(DATETIME, CAST(YEAR(GETDATE()) AS VARCHAR(4)) + 
    '-' + 
    CAST(MONTH(DATEADD(MONTH, -3, GETDATE())) AS VARCHAR(2)) + '-01', 120) 

DECLARE @DateTo AS DATETIME 
SET @DateTo = 
    CONVERT(DATETIME, CAST(YEAR(GETDATE()) AS VARCHAR(4)) + 
    '-' + 
    CAST(MONTH(GETDATE()) AS VARCHAR(2)) + '-01', 120) 

SELECT DISTINCT 
    i.CustomerCode 
FROM 
    Invoice AS i 
WHERE 
    (i.InvoiceDate > @DateFrom AND i.InvoiceDate < @DateTo) 

Le tableau ci-dessous que je comparerai contre sera la table client qui a également un champ de CustomerCode.

Merci d'avance!

EDIT

Après avoir passé les âges à essayer de comprendre cela et juste après quelques minutes de ce message ici affichant je l'ai trouvé une solution. En utilisant la clause NOT IN! Dans mon serveur, cela semble fonctionner plus rapidement que les étapes mentionnées ci-dessous lorsque j'ai testé chacun dans Management Studio.

Answer 1

vous pouvez améliorer votre gestion de rendez-vous avec:

WHERE i.InvoiceDate >= DATEADD(mm,-3,DATEADD(mm,DATEDIFF(mm,0,GETDATE()),0)) 
    AND i.InvoiceDate < DATEADD(mm,DATEDIFF(mm,0,GETDATE()),0) 

avis je> = au début, il vous manque des lignes à la date de départ avec un temps 00:00:00.

pour obtenir tous les clients qui ne disposent pas de factures au cours des 3 derniers mois complets, vous pouvez aussi écrire de cette façon:

SELECT 
    c.CustomerCode 
FROM Customer    c 
    LEFT OUTER JOIN Invoice i ON c.CustomerCode=i.CustomerCode 
     AND i.InvoiceDate >= DATEADD(mm,-3,DATEADD(mm,DATEDIFF(mm,0,GETDATE()),0)) 
     AND i.InvoiceDate < DATEADD(mm,DATEDIFF(mm,0,GETDATE()),0) 
WHERE i.CustomerCode IS NULL 

Answer 2

Pour les clients qui n'ont pas été facturés pendant une certaine période de temps :

SELECT  c.CustomerCode 
FROM  [Customer] AS c 
LEFT JOIN [Invoice] AS i 
     ON c.CustomerCode = i.CustomerCode 
     AND i.InvoiceDate > @DateFrom AND i.InvoiceDate < @DateTo 
WHERE  i.CustomerCode IS NULL 

Bien que je remplacerais les contrôles de plage de dates @DateFrom and @DateTo avec suggestion de KM pour éviter d'utiliser des variables.