Envoi d'e-mails Outlook à une liste de destinataires avec Excel

Question

J'essaie d'envoyer par courrier électronique les données sélectionnées à une liste de destinataires avec Excel vba.

Exemple:
colonne A heures
colonne Taux B
Colonne C totale
Colonne adresse mail D

Nous avons une liste de centaines de personnes avec leurs détails de paiement à envoyer sur une base hebdomadaire base. Nous copions et collons les informations du fichier Excel dans le courrier électronique Outlook.

Existe-t-il un moyen d'envoyer des emails avec Excel VBA?

Answer 1

Cela devrait vous aider à démarrer dans la bonne direction.

Sub SendEmail() 

    Dim OutApp As Object, OutMail As Object 

    Set OutApp = CreateObject("Outlook.Application") 
    Set OutMail = OutApp.CreateItem(0) 

    With OutMail 
     .To = 'Your Contact List 
     .CC = "" 
     .BCC = "" 
     .Subject = "Your Subject Name" 
     .HTMLBody = 'The email body 
     .Display 
    End With 

End Sub 

Answer 2

In column A : Names of the people 
In column B : E-mail addresses 
In column C:Z : Filenames like this C:\Data\Book2.xls (don't have to be Excel files) 

La boucle de volonté Macro à travers chaque ligne de "Sheet1", et s'il y a une adresse e-mail dans la colonne B et le nom de fichier (s) dans la colonne C: Z il va créer un courrier avec cette information et l'envoyer.

Sub Send_Files() 
'Working in Excel 2000-2016 
'For Tips see: http://www.rondebruin.nl/win/winmail/Outlook/tips.htm 
    Dim OutApp As Object 
    Dim OutMail As Object 
    Dim sh As Worksheet 
    Dim cell As Range 
    Dim FileCell As Range 
    Dim rng As Range 

    With Application 
     .EnableEvents = False 
     .ScreenUpdating = False 
    End With 

    Set sh = Sheets("Sheet1") 

    Set OutApp = CreateObject("Outlook.Application") 

    For Each cell In sh.Columns("B").Cells.SpecialCells(xlCellTypeConstants) 

     'Enter the path/file names in the C:Z column in each row 
     Set rng = sh.Cells(cell.Row, 1).Range("C1:Z1") 

     If cell.Value Like "?*@?*.?*" And _ 
      Application.WorksheetFunction.CountA(rng) > 0 Then 
      Set OutMail = OutApp.CreateItem(0) 

      With OutMail 
       .to = cell.Value 
       .Subject = "Testfile" 
       .Body = "Hi " & cell.Offset(0, -1).Value 

       For Each FileCell In rng.SpecialCells(xlCellTypeConstants) 
        If Trim(FileCell) <> "" Then 
         If Dir(FileCell.Value) <> "" Then 
          .Attachments.Add FileCell.Value 
         End If 
        End If 
       Next FileCell 

       .Send 'Or use .Display 
      End With 

      Set OutMail = Nothing 
     End If 
    Next cell 

    Set OutApp = Nothing 
    With Application 
     .EnableEvents = True 
     .ScreenUpdating = True 
    End With 
End Sub 

https://www.rondebruin.nl/win/s1/outlook/amail6.htm