Excel Ole objet Liste des processus encore après quitter

Question

J'ai ce code:

function XlsToStringGrid(AGrid: TStringGrid; AXLSFile: string): Boolean; 
const 
    xlCellTypeLastCell = $0000000B; 
var 
    XLApp, Sheet: OLEVariant; 
    RangeMatrix: Variant; 
    x, y, k, r: Integer; 
begin 
    Result:=False; 
    //Cria Excel- OLE Object 
    XLApp:=CreateOleObject('Excel.Application'); 
    try 

     XLApp.Visible:=False; 

     XLApp.Workbooks.Open(AXLSFile); 
     Sheet:=XLApp.Workbooks[ExtractFileName(AXLSFile)].WorkSheets[1]; 
     Sheet.Cells.SpecialCells(xlCellTypeLastCell, EmptyParam).Activate; 

     x:=XLApp.ActiveCell.Row; 

     y:=XLApp.ActiveCell.Column; 

     AGrid.RowCount:=x; 
     AGrid.ColCount:=y; 

     RangeMatrix:=XLApp.Range['A1', XLApp.Cells.Item[X, Y]].Value; 

     k:=1; 
     repeat 
      for r:=1 to y do 
       AGrid.Cells[(r - 1),(k - 1)]:=RangeMatrix[K, R]; 
      Inc(k,1); 
     until k > x; 
     RangeMatrix:=Unassigned; 
     Result:=True; 

    finally 

     if not VarIsEmpty(XLApp) then 
     begin 
      Sheet:=Unassigned; 
      XLApp.Workbooks[ExtractFileName(AXLSFile)].Close; 
      XLApp.Quit; 
      XLAPP:=Unassigned; 
     end; 
     try freeandnil(XLAPP) except; end; 
     try freeandnil(Sheet) except; end; 
    end; 
end; 

mais après arrêter de fumer avec la commande Quitter, le processus reste toujours dans la liste, les considérations: je fis des recherches et compris que s'il y a un objet référencé il reste dans la liste, mais je crois que j'ai tous libéré.

Answer 1

La commande Quit() d'Excel n'est pas synchrone, le processus peut prendre du temps à se terminer.

Et oui, vous pouvez avoir des références d'objet actives. Vous n'effacez pas RangeMatrix si une exception se produit dans votre boucle repeat, elle peut donc ne pas être désactivée avant la fin de XlsToStringGrid(). Vous devez utiliser plusieurs blocs try/finally, un pour chaque objet.

Et s'il vous plaît, n'appelez PAS FreeAndNil() sur (Ole)Variant variables! Cela ne fonctionne que sur les pointeurs TObject.

Essayez ceci:

function XlsToStringGrid(AGrid: TStringGrid; AXLSFile: string): Boolean; 
const 
    xlCellTypeLastCell = $0000000B; 
var 
    XLApp, WorkBook, Sheet: OLEVariant; 
    RangeMatrix: Variant; 
    x, y, k, r: Integer; 
begin 
    Result := False; 

    XLApp := CreateOleObject('Excel.Application'); 
    try 
    XLApp.Visible := False; 

    XLApp.Workbooks.Open(AXLSFile); 
    try 
     WorkBook := XLApp.Workbooks[ExtractFileName(AXLSFile)]; 
     try 
     Sheet := WorkBook.WorkSheets[1]; 
     try 
      Sheet.Cells.SpecialCells(xlCellTypeLastCell, EmptyParam).Activate; 

      x := XLApp.ActiveCell.Row; 
      y := XLApp.ActiveCell.Column; 

      AGrid.RowCount := x; 
      AGrid.ColCount := y; 

      RangeMatrix := XLApp.Range['A1', XLApp.Cells.Item[X, Y]].Value; 
      try  
      k := 1; 
      repeat 
       for r := 1 to y do 
       AGrid.Cells[(r - 1),(k - 1)] := RangeMatrix[K, R]; 
       Inc(k); 
      until k > x; 
      finally 
      RangeMatrix := Unassigned; 
      end; 

      Result := True; 
     finally 
      Sheet := Unassigned; 
     end; 
     finally 
     WorkBook.Close; 
     WorkBook := Unassigned; 
     end; 
    finally 
     XLApp.Workbooks.Close; 
    end; 
    finally 
    XLApp.Quit; 
    XLAPP := Unassigned; 
    end; 
end;