Interception de propriété des classes de domaine Grails

Question

Je voudrais intercepter des appels aux propriétés de classes de domaine pour implémenter le contrôle d'accès.

Mon premier essai a consisté à remplacer setProperty et getProperty. En faisant cela, j'ai désactivé toutes les bonnes fonctionnalités des classes de domaine Grails, tels que

domainClass.properties = params 

et la conversion automatique des types de données. L'essai suivant consistait à utiliser la DelegatingMetaClass, ce qui m'a permis au moins d'imprimer quelques bons messages de journal autour de l'appel réel. Mais je ne pouvais pas comprendre comment accéder à l'objet réel pour évaluer les autorisations.

Enfin, groovy.lang.Interceptor semble être un bon choix, car je peux accéder à l'objet réel. Mais est-ce la bonne façon? Comment puis-je forcer l'interception de toutes les classes de domaine?

Merci beaucoup d'avance.

Cordialement, Daniel

Answer 1

Vous pouvez remplacer getProperty et setProperty aussi longtemps que vous faites référence à des versions réelles. Ajouter un code comme celui-ci à Bootstrap pour intercepteurs add pour toutes les classes de domaine:

class BootStrap { 

    def grailsApplication 

    def init = { servletContext -> 

     for (dc in grailsApplication.domainClasses) { 
     dc.class.metaClass.getProperty = { String name -> 
      // do stuff before access 
      def result 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       result = metaProperty.getProperty(delegate) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after access 
      result 
     } 

     dc.class.metaClass.setProperty = { String name, value -> 
      // do stuff before update 
      def metaProperty = delegate.class.metaClass.getMetaProperty(name) 
      if (metaProperty) { 
       metaProperty.setProperty(delegate, value) 
      } 
      else { 
       throw new MissingPropertyException(name, delegate.class) 
      } 
      // do stuff after update 
     } 
     } 
    } 

    def destroy = {} 
}